* INDICATORI:
      * 80 : ATTIVO -> CAMPO TITOLO VUOTO (TITOLV)
      * 81 : ATTIVO -> CAMPO AUTORE VUOTO (AUTORV)
      * 82 : ATTIVO -> CAMPO EDITRICE VUOTO (EDITRV)
      * 83 : ATTIVO -> CAMPO DIVERSO DA 'C' O 'E' (TIPOV)
      * 85 : ATTIVO -> CAMPO FILENAME RIEMPITO E 'C' O VUOTO E' 'E' (FILENV)
      * 86 : ATTIVO -> ERRORE GENERICO
      **
     FINPBOK  CF  E                    WORKSTN
     FBOKPF   UF  E                    DISK                      A
      *
     E                    MSG     1  10 20
     E                    TMP         3 20
      *  << RIDEFINIZIONE DEI CAMPI DI I/O >>
      * (IL CAMPO DI OUTPUT ERRORI E' ERRVID)
     IMAIN
     I              TITOLO                          TITOLV
     I              AUTORE                          AUTORV
     I              EDITRICE                        EDITRV
     I              SERIALE                         SERIAV
     I              EDIZIONE                        EDIZIV
     I              VOLUME                          VOLUMV
     I              TIPO                            TIPOV
     I              FILENAME                        FILENV
     IBOOKDATA
     I              TITOLO                          TITOLF
     I              AUTORE                          AUTORF
     I              EDITRICE                        EDITRF
     I              EDIZIONE                        EDIZIF
     I              SERIAL                          SERIAF
     I              VOLNUM                          VOLUMF
     I              TIPO                            TIPOF
     I              NOMEFILE                        FILENF
      *
      *  << INIZIO PROGRAMMA PRINCIPALE >>
     C                     DO   *HIVAL
     C                     EXFMTMAIN
     C   KC                LEAVE
     C                     SETOF                         86
     C                     MOVE *ZEROS    EN      10
     C                     MOVEA*BLANK    TMP
      *
     C           TITOLV    COMP *BLANK                   80
     C   80                Z-ADD2         TR      10
     C   80                EXSR SRERR
     C           AUTORV    COMP *BLANK                   81
     C   81                Z-ADD3         TR
     C   81                EXSR SRERR
     C           EDITRV    COMP *BLANK                   82
     C   82                Z-ADD4         TR
     C   82                EXSR SRERR
     C           TIPOV     COMP 'C'                  8383
     C   83      TIPOV     COMP 'E'                  8383
     C   83                Z-ADD5         TR
     C   83                EXSR SRERR
     C           FILENV    IFNE *BLANK
     C           TIPOV     ANDEQ'C'
     C           FILENV    OREQ *BLANK
     C           TIPOV     ANDEQ'E'
     C                     SETON                         85
     C                     Z-ADD6         TR
     C                     EXSR SRERR
     C                     ELSE
     C                     SETOF                         85
     C                     ENDIF
      *****************
      * INSERIMENTO CONDIZIONATO BLOCCATO DA:
      * 1) TITOLO MANCANTE
      * 2) AUTORE MANCANTE
      * 3) EDITRICE MANCANTE
      * 4) TIPO DIVERSO DA 'C' O 'E'
      * 5) TIPO 'E' SE CAMPO FILENAME VUOTO
      * 6) TIPO 'C' E FILENAME PIENO
      *****************
     C  N86                DO
     C                     MOVELTITOLV    TITOLF
     C                     MOVELAUTORV    AUTORF
     C                     MOVELEDITRV    EDITRF
     C                     MOVELSERIAV    SERIAF
     C                     MOVELEDIZIV    EDIZIF
     C                     MOVELVOLUMV    VOLUMF
     C                     MOVELTIPOV     TIPOF
     C                     MOVELFILENV    FILENF
     C                     WRITEBOOKDATA
     C                     CLEARMAIN
     C                     MOVELMSG,1     ERRVID
     C                     ENDDO
      *  << TERMINE INSERIMENTO CONDIZIONATO >>
      *
      *  << IN CASO DI ERRORI RILEVATI >>
     C   86                MOVEATMP       ERRVID
     C   01N01             READ BOOKDATA                 01
     C   01N01             UPDATBOOKDATA
     C                     ENDDO
     C                     SETON                         LR
      *
      *  << SUBROUTINE ERRORE - INIZIO >>
     C           SRERR     BEGSR
     C                     SETON                         86
     C                     ADD  1         EN
     C           EN        IFLE 3
     C                     MOVE *BLANK    ERRVID
     C                     MOVELMSG,TR    TMP,EN
     C                     ENDIF
     C           EN        IFGT 3
     C                     MOVE '+'       ERRVID
     C                     ENDIF
     C                     ENDSR
      *  << SUBROUTINE ERRORE - FINE >>
**                  *
* INSER. AVVENUTO
* TITOLO MANCANTE
* AUTORE MANCANTE
* EDITRICE MANCANTE
* TIPO NON VALIDO
* FILENAME NON VALI.